NOTE: Due to the time delay between the camera being triggered and it recording an image (due to the relatively slow shutter response times of most cameras), this system may not be useful for recording images of fast-moving objects. Test its effectiveness for your application before deploying the setup.

To achieve faster image captures you could trigger a flash directly and bypass the camera trigger altogether. Unfortunately, this means you would need to have the shutter remain open for a long period of time while waiting for something to trigger an image which will probably increase the background exposure in your image. You could use a low ISO (100), a small lens aperture and record images at night with a black background to help decrease this background exposure. This method could also be used in a dark room with all the lights turned off.

An easy way to connect the trigger directly to a flash is to pick up an inexpensive flash hot shoe adapter with a “sync cord” connector (the small round connector port shown in the image below). All you need to do is strip the two wires in the sync cord and attach them to the camera side of the trigger circuit (shown below). You don’t need a resistor in the flash side of the trigger circuit with this method. The flash is triggered when the two wires are connected, and that's exactly what this trigger circuit does. This system will give much quicker image capture times compared to relying on the in-camera shutter mechanism.

Hot Shoe Adapter with a “Sync Cord” Connector

Camera and Flash Trigger Setup

More information about the camera trigger setup is available HERE .

Powerup Sequence: Tun on the camera, then turn on the Arduino.

//------------- Code Starts Here ----------------------------

//-----------------------------------------
//Published by IntroductionToArduino.com
//Created by Paul Illsley (www.paulillsley.com)
//Please use and share so others can enjoy
//-----------------------------------------

//======================= Start of Settings ===================

// *** Set the Minimum Distance trigger value (in cm) ***
int Minimum_Distance = 100;

// *** Set the Maximum Distance trigger value (in cm) ***
int Maximum_Distance = 101;

// *** Set the Delay value to wait for the camera's flash to recharge (in seconds) ***
int delay_seconds = 5;

// Number of iterations before the camera records a new frame
int iterations = 10000;

//======================= End of Settings ====================

#include <Arduino.h>     // Including the Arduino library
#include <Wire.h>        // Including the Wire library
#include <TFLI2C.h>      // Including the TFLI2C (TFLuna-I2C) Library (this needs to be installed)

TFLI2C tflI2C;

//Defining pin 13 for the Confirmation LED
#define LED 13

// Defining pin 4 as the "Camera Trigger"
#define Camera_Trigger 4

// Defining pin 5 as the "Flash Trigger"
#define Flash_Trigger 5

// Creating a variable called Counter and assigning it a value of 0
int Counter = 0;

int16_t  Distance_cm;    // distance in centimeters
int16_t  tfAddr = TFL_DEF_ADR;  // Use this default I2C address
 
void setup(){
  Serial.begin(115200);// Initalizing the Serial Port at a baud rate of 115200
    
  Wire.begin();// Initalizing the Wire Library
    
  // setting pin modes as outputs
  pinMode(13,OUTPUT);
    
  // Declaring pin 4 (Camera_Trigger) as an output
  pinMode(Camera_Trigger , OUTPUT);

  // Declaring pin 5 (Flash_Trigger) as an output
  pinMode(Flash_Trigger , OUTPUT);

  // Turning pin 4 (Camera_Trigger) off
  digitalWrite(Camera_Trigger , LOW);
}
 
void loop(){

  digitalWrite(LED , LOW); // Turning off the LED (Pin 13)

  // Open the camera's shutter 
  digitalWrite(Camera_Trigger , HIGH);
  
  // Pulling a distance value (in cm) from the TF-Luna 
  tflI2C.getData(Distance_cm, tfAddr);

  // Write the distance to the serial monitor
  Serial.print("Distance (cm): ");
  Serial.println(Distance_cm);


  // Checking the distance for "In Trigger Zone"  LED
  // If the distance is above or equal to the Minimum and below or equal to the Maximum
  // turn onn the LED
  if ((Distance_cm >= Minimum_Distance) && (Distance_cm <= Maximum_Distance)){
      
  // Trigger the Flash then close the shutter
  // Wait for the flash to recharge
  // Reset iteration counter to 0 and delay 500 milliseconds
    
  digitalWrite(Flash_Trigger , HIGH);
  delay(10);
  digitalWrite(Flash_Trigger , LOW);
  digitalWrite(Camera_Trigger , LOW);
  delay((delay_seconds)*1000); 
  Counter = 0;
  delay(500);
 }

  // If the number of iterations is reached without being triggered, 
  // triggeer the camera to open a new frame and reset the counter to 0
  // Delay 500 milliseconds
  if (Counter == (iterations)){
  digitalWrite(Camera_Trigger , LOW);
  Counter = 0;
  delay(500);
 }

  // If the camera isn't triggered, add one to the counter value
  Counter = Counter + 1;

  // Print the iteration count number
  Serial.println(Counter);

}
//------------- Code Stops Here ----------------------------